components/IText.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

pragma ComponentBehavior: Bound

import QtQuick

import qs.config

Text {
    id: root

    property bool animate: false
    property real animateFrom: 0
    property real animateTo: 1

    renderType: Text.NativeRendering // or Text.CurveRendering(much more expansive) or Text.QtRendering for faster
    textFormat: Text.PlainText
    elide: Text.ElideRight
    color: Colors.foreground1

    font {
        family: Style.font.family.iosevka
        // pointSize: root.pixelSize
        pixelSize: Style.font.size.larger
    }

    Behavior on color {
        ColorAnimation {
            duration: Style.anim.durations.normal
            easing.type: Easing.BezierSpline
            easing.bezierCurve: Style.anim.curves.standard
        }
    }

    Behavior on text {
        enabled: root.animate

        SequentialAnimation {
            Anim {
                to: root.animateFrom
                easing.bezierCurve: Style.anim.curves.standardAccel
            }
            PropertyAction {}
            Anim {
                to: root.animateTo
                easing.bezierCurve: Style.anim.curves.standardDecel
            }
        }
    }

    component Anim: NumberAnimation {
        target: root
        property: "scale"
        duration: General.animationDuration / 4
        easing.type: Easing.BezierSpline
    }
}